Refactoring: move all apps inside a sub folder
CI / Release Gitea (push) Successful in 32s
CI / Vérifications et paquet (push) Successful in 47s

This commit is contained in:
stilobique committed 2026-11-08 14:28:28 +01:00
1 parent 33e4fe0c4e
commit b1ca2a7cff
41 files changed
+54 -45

No files matched your search

+86
View File
@@ -0,0 +1,86 @@
import QtQuick 2.5
import "../Shared"
import "../Shared/Remote.js" as Remote
// Pile de navigation entre les écrans de Views/.
// push("ServerAdd") charge Views/ServerAddView.qml ; la touche Retour dépile.
// Chaque écran reçoit `navigator` et `session`, plus les propriétés passées à push().
FocusScope {
id: root
property var session: null
property int depth: 0
readonly property bool fullscreen: loader.item !== null && loader.item.fullscreen === true
property var _stack: []
function push(name, props) {
_stack.push({ name: name, props: props || {} });
_load();
}
function replace(name, props) {
if (_stack.length > 0)
_stack.pop();
push(name, props);
}
function pop() {
if (_stack.length <= 1)
return false;
_stack.pop();
_load();
return true;
}
function reset(name, props) {
_stack = [];
push(name, props);
}
// Ouvre l'écran adapté à un élément du catalogue (Session._toItem()).
function openItem(item) {
if (item.type === "CollectionFolder")
push("Library", { library: { id: item.id, name: item.name, collectionType: item.collectionType } });
else if (item.type === "Season")
push("Season", { seriesId: item.seriesId, seasonId: item.id, seasonName: item.name,
seriesName: item.seriesName });
else
push("Details", { itemId: item.id });
}
function _load() {
var entry = _stack[_stack.length - 1];
var props = { navigator: root, session: root.session };
for (var key in entry.props)
props[key] = entry.props[key];
depth = _stack.length;
loader.setSource(Qt.resolvedUrl("../Views/" + entry.name + "View.qml"), props);
}
Loader {
id: loader
anchors.fill: parent
focus: true
onLoaded: {
fadeIn.restart();
var target = item.initialFocus ? item.initialFocus : item;
target.forceActiveFocus();
}
}
NumberAnimation {
id: fadeIn
target: loader.item
property: "opacity"
from: 0
to: 1
duration: 180
}
// Retour : on dépile ; à la racine, la touche remonte (fermeture de l'app).
Keys.onPressed: {
if (Remote.isBack(event.key) && pop())
event.accepted = true;
}
}