Refactoring: move all apps inside a sub folder
This commit is contained in:
1 parent
33e4fe0c4e
commit
b1ca2a7cff
41 files changed
+54
-45
No files matched your search
@@ -0,0 +1,145 @@
|
||||
import QtQuick 2.5
|
||||
import "../Components"
|
||||
import "../Shared"
|
||||
import "../Shared/Remote.js" as Remote
|
||||
|
||||
// Écran 3 : choix de l'utilisateur parmi les comptes publics du serveur.
|
||||
// Si le serveur masque ses comptes, seule la carte « Ajouter un compte » est proposée,
|
||||
// plus les comptes de test éventuels (freebox-jellyfin deploy --user).
|
||||
Page {
|
||||
id: page
|
||||
|
||||
property var publicUsers: []
|
||||
// Comptes publics + comptes de test absents de la liste publique.
|
||||
property var users: mergeUsers(publicUsers, page.session ? page.session.devUsers : [])
|
||||
property bool loading: true
|
||||
property bool busy: false
|
||||
property string error: ""
|
||||
|
||||
title: "Qui regarde ?"
|
||||
subtitle: page.session && page.session.currentServer
|
||||
? page.session.currentServer.name + " · " + page.session.currentServer.address
|
||||
: ""
|
||||
initialFocus: userList
|
||||
|
||||
function mergeUsers(publicList, devList) {
|
||||
var result = publicList.slice();
|
||||
for (var i = 0; i < devList.length; i++) {
|
||||
var known = false;
|
||||
for (var j = 0; j < publicList.length; j++)
|
||||
known = known || publicList[j].name.toLowerCase() === devList[i].name.toLowerCase();
|
||||
if (!known)
|
||||
result.push({ name: devList[i].name, hasPassword: true, devPassword: devList[i].password });
|
||||
}
|
||||
return result;
|
||||
}
|
||||
|
||||
function signInAs(name, password) {
|
||||
error = "";
|
||||
busy = true;
|
||||
page.session.authenticate(name, password, function (err) {
|
||||
page.busy = false;
|
||||
if (err) {
|
||||
page.error = err;
|
||||
return;
|
||||
}
|
||||
page.navigator.reset("Home");
|
||||
});
|
||||
}
|
||||
|
||||
function openUser(index) {
|
||||
if (busy)
|
||||
return;
|
||||
// Dernière carte : « Ajouter un compte » → identifiant libre.
|
||||
if (index >= users.length) {
|
||||
page.navigator.push("Login");
|
||||
return;
|
||||
}
|
||||
var user = users[index];
|
||||
// Compte de test avec mot de passe fourni : connexion directe.
|
||||
if (user.devPassword !== undefined) {
|
||||
signInAs(user.name, user.devPassword);
|
||||
return;
|
||||
}
|
||||
if (user.hasPassword) {
|
||||
page.navigator.push("Login", { username: user.name });
|
||||
return;
|
||||
}
|
||||
// Compte sans mot de passe : connexion directe, comme sur Android TV.
|
||||
signInAs(user.name, "");
|
||||
}
|
||||
|
||||
Component.onCompleted: {
|
||||
page.session.loadPublicUsers(function (err, users) {
|
||||
page.loading = false;
|
||||
if (err) {
|
||||
page.error = err;
|
||||
return;
|
||||
}
|
||||
page.publicUsers = users;
|
||||
});
|
||||
}
|
||||
|
||||
Component.onDestruction: if (page.session) page.session.cancel()
|
||||
|
||||
ListView {
|
||||
id: userList
|
||||
anchors {
|
||||
top: parent.top
|
||||
left: parent.left
|
||||
right: parent.right
|
||||
}
|
||||
height: 220
|
||||
orientation: ListView.Horizontal
|
||||
spacing: Theme.spacingL
|
||||
model: page.users.concat([{ name: "Ajouter un compte", add: true }])
|
||||
|
||||
delegate: UserCard {
|
||||
name: modelData.name
|
||||
addCard: modelData.add === true
|
||||
highlighted: ListView.isCurrentItem && userList.activeFocus
|
||||
onClicked: {
|
||||
userList.currentIndex = index;
|
||||
page.openUser(index);
|
||||
}
|
||||
}
|
||||
|
||||
Keys.onPressed: {
|
||||
if (Remote.isAccept(event.key) && currentIndex >= 0) {
|
||||
event.accepted = true;
|
||||
page.openUser(currentIndex);
|
||||
}
|
||||
}
|
||||
KeyNavigation.priority: KeyNavigation.AfterItem
|
||||
KeyNavigation.down: changeServerButton
|
||||
}
|
||||
|
||||
Text {
|
||||
id: statusText
|
||||
anchors {
|
||||
top: userList.bottom
|
||||
left: parent.left
|
||||
right: parent.right
|
||||
}
|
||||
visible: text !== ""
|
||||
text: page.busy ? "Connexion…"
|
||||
: page.loading ? "Chargement des utilisateurs…"
|
||||
: page.error !== "" ? page.error
|
||||
: page.users.length === 0 ? "Les comptes de ce serveur ne sont pas affichés publiquement : choisissez « Ajouter un compte » pour vous connecter."
|
||||
: ""
|
||||
color: page.error !== "" && !page.busy ? Theme.error : Theme.textMuted
|
||||
font.pixelSize: Theme.fontBody
|
||||
wrapMode: Text.WordWrap
|
||||
}
|
||||
|
||||
FocusButton {
|
||||
id: changeServerButton
|
||||
anchors {
|
||||
left: parent.left
|
||||
bottom: parent.bottom
|
||||
}
|
||||
text: "Changer de serveur"
|
||||
KeyNavigation.up: userList
|
||||
onClicked: page.navigator.reset("ServerSelect")
|
||||
}
|
||||
}
|
||||
Reference in new issue
Block a user