Files
stilobique b1ca2a7cff
CI / Release Gitea (push) Successful in 32s
CI / Vérifications et paquet (push) Successful in 47s
Refactoring: move all apps inside a sub folder
2026-11-08 14:28:28 +01:00

75 lines
2.2 KiB
QML

import QtQuick 2.5
import "../Components"
import "../Shared"
import "../Shared/Remote.js" as Remote
// Écran 1 : choix d'un serveur enregistré ou découvert sur le réseau local.
Page {
id: page
title: "Sélectionner un serveur"
subtitle: serverList.count > 0
? "Choisissez le serveur Jellyfin auquel vous connecter."
: "Aucun serveur enregistré. Ajoutez l'adresse de votre serveur Jellyfin."
initialFocus: serverList.count > 0 ? serverList : addButton
function openServer(index) {
page.session.selectServer(index);
page.navigator.push("UserSelect");
}
ListView {
id: serverList
anchors {
top: parent.top
left: parent.left
right: parent.right
bottom: addButton.top
bottomMargin: Theme.spacingL
}
clip: true
spacing: Theme.spacingS
model: page.session ? page.session.servers : null
// Serveur ajouté après l'affichage (dev-config) : on y place le focus.
onCountChanged: {
if (count > 0 && addButton.activeFocus) {
currentIndex = 0;
forceActiveFocus();
}
}
delegate: ServerItem {
width: serverList.width
name: model.name
address: model.address
highlighted: ListView.isCurrentItem && serverList.activeFocus
onClicked: {
serverList.currentIndex = index;
page.openServer(index);
}
}
Keys.onPressed: {
if (Remote.isAccept(event.key) && currentIndex >= 0) {
event.accepted = true;
page.openServer(currentIndex);
}
}
// Laisse la ListView gérer Haut/Bas ; on ne sort qu'en bout de liste.
KeyNavigation.priority: KeyNavigation.AfterItem
KeyNavigation.down: addButton
}
FocusButton {
id: addButton
anchors {
left: parent.left
bottom: parent.bottom
}
text: "Ajouter un serveur"
KeyNavigation.up: serverList.count > 0 ? serverList : null
onClicked: page.navigator.push("ServerAdd")
}
}